Paschen-Back Effect

from Essential Mathematica for Students of Science
© James J. Kelly, 1998
Last revised: January, 2006

Introduction

In the absence of magnetic interactions, the ground state of a hydrogen atom would display a 4-fold degeneracy arising from the 2×2 combinations its two spin-(1/2)constituents.  The hyperfine interaction between the electron and proton spins, represented by an interaction hamiltonian of the form (Subscript[H, hf]) =  (Subscript[ε, 0]) 
          (Subscript[S, e])·(Subscript[S, p]) alleviates part of this degeneracy.  Thus, one finds the singlet state (with total spin zero) is approximately 5.9 μeV lower in energy than the triplet state (with total spin 1); nevertheless, a 3-fold degeneracy remains among the triplet substates.  Now suppose that the hydrogen atom is placed in an external magnetic field.  The interaction between the spins and the external magnetic field can be represented by an interaction hamiltonian of the form (Subscript[H, ext]) =  ((Subscript[γ, e]) 
                (Subscript[S, e]) -  (Subscript[γ, p]) (Subscript[S, p]))·B and removes the remaining degeneracy, such that four distinct energy eigenvalues emerge.  For relatively weak magnetic external fields, the hyperfine interaction dominates and it is convenient to express the eigenstates in terms of the eigenstates of total spin; the behavior of the energy levels under these conditions is described as the Zeeman effect.  For strong external magnetic fields, it is more convenient to employ eigenstates of the individual spin components relative to the external field and the linear dependence of the energy levels is described as the Paschen-Back effect.  This effect is important because it provides a means for measuring the proton gyromagnetic ratio.

Glossary:
	(Subscript[ε, 0])		= hyperfine coupling constant
	(Subscript[S, e])		= electron spin
	(Subscript[S, p])		= proton spin
	B		= external magnetic field
	(Subscript[γ, e]) = (Subscript[g, e]) (Subscript[μ, B])	= magnetic coupling for electron
	(Subscript[γ, p]) = (Subscript[g, p]) (Subscript[μ, N])	= magnetic coupling for proton
	(Subscript[μ, B])		= Bohr magneton
	(Subscript[μ, N])		= nuclear magneton
	(Subscript[g, e])		= electron gyromagnetic ratio
	(Subscript[g, p])		= proton gyromagnetic ratio

Initialization

ClearAll["Global`*"];
Off[General::spell, General::spell1];
$TextStyle = {FontFamily -> "Times", 
          FontSize -> 12};

Needs["Utilities`Notation`"];
Needs["Miscellaneous`PhysicalConstants`"];
Needs["Miscellaneous`Units`"]

Off[Symbolize::"boxSymbolExists"];

Symbolize[(Subscript[ε, x])_]; Symbolize[(Subscript[γ, x])_]; Symbolize[(Subscript[δ, x])_]

norm[v_] := v . v;
normalize[v_] := 
        Module[{vnorm}, vnorm = v . v; vnew = (v/(Sqrt[vnorm]))];

Clear[normalize];
normalize[v_] := (v/(Sqrt[v . v]))

The following simplification functions use known properties of the physical constants to simplify algebraic results as much as possible.

MyAssumptions = {(Subscript[γ, e]) > 0, (Subscript[γ, p]) > 0, (Subscript[γ, 1]) > 
            0, (Subscript[γ, 2]) > 0, B > 0, (Subscript[ε, 0]) > 0, 
          ratio > 1, (Subscript[δ, e]) + (Subscript[δ, p]) ≥ (Subscript[ε, 0])};
MySimplify = 
        Simplify[#, MyAssumptions] &;
MyFullSimplify = FullSimplify[#, MyAssumptions] &;

Establish Hamiltonian

It is convenient to express the hamiltonian in terms of the eigenstates |J,
          M⟩ of total spin, arranged in the order |00⟩, |10⟩, |11⟩, \(TraditionalForm\`|1,\(-1\)⟩\).  Thus, evaluating the matrix elements, we obtain the following hamiltonian matrix.

hamiltonian = Array[h, {4, 4}];

h[1, 1] = -((3 )/4) (Subscript[ε, 0]);  
    h[2, 2] = (1/4) (Subscript[ε, 0]);
h[3, 3] = (1/4) (Subscript[ε, 0]) + 
          (1/2) ((Subscript[γ, e]) - (Subscript[γ, p])) B;
h[4, 
          4] = (1/4) (Subscript[ε, 0]) - (1/2) ((Subscript[γ, e]) - (Subscript[γ, p])) B;
h[1, 
          2] = +(1/2) ((Subscript[γ, e]) + (Subscript[γ, p])) B;
h[1, 
          3] = h[1, 
            4] = h[2, 3] = h[2, 4] = h[3, 4] = 0;
h[2, 1] = h[1, 2]; h[3, 1] = h[1, 3]; h[3, 2] = h[2, 3];
h[4, 1] = h[1, 4]; h[4, 2] = h[2, 4]; h[4, 3] = h[3, 4];

It is convenient to express the field strengths in Tesla and energies in (10^(-6)) eV.

values = {(Subscript[ε, 0]) -> 
              5.87 microElectronVolt, (Subscript[γ, e]) -> 
              2 Convert[BohrMagneton, 
                  (ElectronVolt/Tesla)], (Subscript[γ, p]) -> 
              2×2.78 Convert[NuclearMagneton, (ElectronVolt/Tesla)]} //. 
          ElectronVolt -> 
            (10^6) microElectronVolt //. {microElectronVolt -> 1, 
          Tesla -> 1}

It will also be useful to define linear transformations between ((Subscript[γ, e]), (Subscript[γ, p]))  and their sum and difference ((Subscript[γ, 1]), (Subscript[γ, 2])), such that

transep12 = {(Subscript[γ, e]) -> (((Subscript[γ, 1]) + (Subscript[γ, 2]))/2), (Subscript[γ, p]) -> (((Subscript[γ, 1]) - (Subscript[γ, 2]))/2)};

trans12ep = {(Subscript[γ, 1]) -> (Subscript[γ, e]) + (Subscript[γ, p]), (Subscript[γ, 2]) -> (Subscript[γ, e]) - (Subscript[γ, p])};

Note that (Subscript[γ, 1]) ≈ (Subscript[γ, 2]).

{(Subscript[γ, 1]), (Subscript[γ, 2])}  /. trans12ep /. values

Diagonalize Hamiltonian

Eigenvalues

eigenvalues = 
      Eigenvalues[hamiltonian /. transep12]  // MySimplify

energies = Thread[{(Subscript[ε, 1]), (Subscript[ε, 2]), (Subscript[ε, 3]), (Subscript[ε, 4])} -> eigenvalues] /. trans12ep /. 
        values

Determine field for which the two upper levels cross

eq2 = (Subscript[ε, 2]) == (Subscript[ε, 4]) /. 
          energies;

Solve[eq2, B]

This crossing occurs at a very large field strength.

Plot level structure for moderate B

\(\(plot1 = 
        Plot[Evaluate[{ε\_1, ε\_2, ε\_3, ε\_4} /. energies, {B, 0, 0.2}], 
          AxesLabel -> {"B (T)", "E (µeV)"}];\)\)

The substates with M = ±1 are eigenstates of the interaction Hamiltonians and their energies are linear in the external field strength.  The substates with M = 0 and J = 0 or 1, are mixed by the interaction, so that their energies are quadratic functions of B.  For small B, the |J, M⟩ states are approximate eigenstates.  For large B the approximate eigenstates are have unique spin-projection along the field since the hyperfine interaction becomes irrelevant.  Therefore, for moderate B the states are ordered with increasing energy as
	|J, 
          M⟩  =  |0, 
          0⟩, \(TraditionalForm\`|1, \(-1\)⟩\), |1, 0⟩, |1, 1⟩   for small B
	\(TraditionalForm\`|S\_z, 
          I\_z⟩\  = \ |\(-+\)⟩\), |--⟩, |+-⟩, |++⟩   for moderate B.
For very large B, the |+-⟩ state crosses through the |++⟩ and has the higher energy.

Eigenvectors

vectors = Eigenvectors[hamiltonian /. transep12]

Evaluate mixing between M=0 states.

We define the tangent of the mixing angle to be the ratio between the amplitudes for the |00⟩ and |10⟩ basis vectors for the state that asymptotically becomes |+-⟩.

mixingAngle[
        B] = (((ArcTan[vectors[[4, 1]]] /. trans12ep /. values) 180. )/π)

plot2 = 
        Plot[Evaluate[mixingAngle[B] /. values, {B, 0.00001, 5.0}], 
          FrameLabel -> {"B (T)", "mixing angle", "Mixing of \
\[LeftBracketingBar]00⟩ and \[LeftBracketingBar]10\
⟩ States", " "}, 
          PlotRange -> {{0, 5}, {0, 90}}, GridLines -> Automatic, 
          Frame -> True];

Large field limit

(normalize /@ Limit[vectors, B -> ∞]) // 
      MyFullSimplify

Small field limit

The order of operations must be chosen with care to avoid indeterminate results in evaluating the B -> 0 limit.

Limit[normalize /@ MySimplify[Normal[Series[vectors, {B, 0, 2}]]], 
        B -> 0] // MySimplify

Determine ratio of proton to electron magnetic couplings from spin-flip transition energies

A precise measurement of the proton anomalous magnetic moment can be based upon spin-flip transitions in the Paschen-Back (large field) limit.  In that limit the ratio between proton and electron spin-flip energies is equal to the ratio between their magnetic coupling constants.

The experiment is done by measuring the absorption of microwave radiation tuned to the energy differences between various pairs of levels split by a strong magnetic field.  The relatively small difference between the lowest two energy levels is determined by (Subscript[γ, p]) while the much larger difference between the second and third levels is determined by (Subscript[γ, e]).  Hence, to lowest order the ratio between these two frequencies for the same magnetic field gives the ratio between gyromagnetic factors, up to small corrections.  Note that the use of ratios tends to eliminate systematic errors.  This relationship between the transition energies and gyromagnetic factors is derived below, including the corrections due to the hyperfine coupling.

Determine the transition energies

We must be careful to identify the appropriate eigenvalues, whose order may depend upon the version of Mathematica that is employed.

eq1 = {(Subscript[δ, e]) == 
                eigenvalues[[4]] - 
                  eigenvalues[[2]], (Subscript[δ, p]) == 
                eigenvalues[[2]] - 
                  eigenvalues[[3]]} /. 
            trans12ep /. {(Subscript[γ, p]) -> -ratio (Subscript[γ, e])}  // 
        MySimplify

Some of the results below depend upon the combination (Subscript[δ, e]) + (Subscript[δ, p])

eigenvalues[[2]] - 
          eigenvalues[[3]] + 
          eigenvalues[[4]] - 
          eigenvalues[[2]] /. trans12ep // 
      MySimplify

which satisfies the inequality \(TraditionalForm\`δ\_e + δ\_p ≥ ε\_0\).  Therefore, this inequality was included in MyAssumptions in order to optimize the simplification functions.

Large field limit

eq2 = eq1 /. {(Subscript[ε, 0]) -> 0}  // MySimplify

Solve[eq2, ratio, B]

General case

sol1 = Solve[eq1, {ratio, B}] // MyFullSimplify

Use (Subscript[ε, 0]) -> 0 limit to select desired solution.

(sol1 /. {(Subscript[ε, 0]) -> 0} // 
        MySimplify)

MySimplify[
      Series[ratio /. 
          sol1[[2]], {(Subscript[ε, 0]), 0, 1}]]