Recoil Polarization Bases

James J. Kelly

Several bases useful for analysis of recoil polarization in \(TraditionalForm\`\((\(e\& ⇀ \), \(e\^′\) \(N\& ⇀ \))\)\) reactions and their interrelationships are developed.

Last revised: November 15, 1999

Defaults and packages

ClearAll["Global`*"];
Off[General::spell, General::spell1]

Needs["Utilities`Notation`"]

Symbolize[\(x\&^\)];Symbolize[\(y\&^\)];Symbolize[\(z\&^\)];
Symbolize[\(t\&^\)];Symbolize[\(n\&^\)];Symbolize[\(ℓ\&^\)];
Symbolize[\(a\&^\)];Symbolize[\(b\&^\)];Symbolize[\(c\&^\)]; 
Symbolize[\(d\&^\)];Symbolize[\(e\&^\)];Symbolize[\(f\&^\)];
Symbolize[(Subscript[θ, s])];

Rotation matrices

We begin with a primitive basis in which \(TraditionalForm\`z\&^ = q\&^\) is along the virtual photon, \(TraditionalForm\`y\&^ ∝ k\&^\_i×k\&^\_f\) is normal to the electron scattering plane, and \(TraditionalForm\`x\&^ = y\&^×z\&^\) is transverse within that plane.  It is convenient to call this the photon basis.  Other bases can be generated by a sequence of rotations based upon the matrices

rotz[θ_] := {{Cos[θ], -Sin[θ], 
            0}, {Sin[θ], Cos[θ], 0}, {0, 0, 1}};
rotx[θ_] := {{1, 0, 0}, {0, 
            Cos[θ], -Sin[θ]}, {0, Sin[θ], 
            Cos[θ]}};
roty[θ_] := {{Cos[θ], 0, Sin[θ]}, {0, 1, 
          0}, {-Sin[θ], 0, Cos[θ]}}

which generate counterclockwise rotations of a vector about the specified coordinate axis.  Note that these matrices produce active rotations of a vector wrt the original coordinate system.

Next, we define a general rotation in terms of three Euler angles representing rotation about \(TraditionalForm\`z\&^\) through angle α, followed by rotation about \(TraditionalForm\`\(y\^′\)\&^\) through angle β, and finally rotation about \(TraditionalForm\`\(z\^″\)\&^\) through angle γ.  One can show that the same transformation is achieved by rotation γ about the \(TraditionalForm\`\(z\&^\)\), followed by rotation β about the original \(TraditionalForm\`\(y\&^\)\) axis, and finally rotation α about the original \(TraditionalForm\`\(z\&^\)\) axis, whereby

euler[α_, β_, γ_] := 
      rotz[α] . roty[β] . rotz[γ]

euler[α, β, γ] // Simplify

Several special cases are shown below, where the columns provide the transformed basis vectors in terms of the original coordinate system.

euler[ϕ, 0, 0] // MatrixForm

euler[0, θ, 0] // MatrixForm

euler[ϕ, 0, 0] . {x, y, 0}

euler[0, θ, 0] . {x, 0, z}

Normalized cross product

It will be useful to define a vector cross product with unit normalization.

NormalizedCrossProduct[a_, b_] := 
      Module[{c}, c = Cross[a, b]; Simplify[c/(Sqrt[c . c])]]

Transformation matrices

The following function constructs the transformation matrix from basis1 to basis2. Note that this is a passive rotation of the coordinate system and produces the polarization components with respect to the new basis.

TransformationMatrix[basis2_, basis1_] := 
      Table[Dot[basis1[[i]], 
            basis2[[j]]], {j, 1, 3}, {i, 
            1, 3}] // Simplify

Reaction basis

The most common basis places the longitudinal direction along the momentum, normal perpendicular to the reaction plane, and transverse in the reaction plane.  We denote the reaction basis vectors \({\(t\&^\), \(n\&^\), \(ℓ\&^\)}\). Let ϕ represent the dihedral angle between the scattering and reaction planes and θ represent the polar angle between the ejectile momentum and the virtual photon.  The basis vectors then become

\({t\&^, n\&^, ℓ\&^} = 
      Transpose[euler[ϕ, θ, 0]] // Simplify\)

euler[ϕ, θ, 0] . {0, 0, 1}

euler[ϕ, θ, 0] . {1, 0, 0}

\(n\&^ /. ϕ -> 0\)

\(t\&^ /. ϕ -> 0\)

\(t\&^ /. ϕ -> π\/2\)

Unfortunately, the reaction basis has the undesirable property that its vertical component reverses sign as \(TraditionalForm\`\(p\&^\)\) moves from one side of \(TraditionalForm\`\(q\&^\)\) to the other.

\(\(ReactionBasis = {t\&^, n\&^, ℓ\&^};\)\)

ReactionBasis /. ϕ -> 0 // Simplify

ReactionBasis /. ϕ -> π // Simplify

Similarly,  \(TraditionalForm\`t\&^ . x\&^\) also reverses sign abruptly.  These sign reversals are reflected in abrupt changes in the polarization components on either side of \(TraditionalForm\`q\&^\).  Smoother behavior is achieved using the polarimeter basis developed below.  First, however, we give the matrix which transforms the polarization components from the reaction basis to the photon basis.

ReactionToPhoton = 
        TransformationMatrix[IdentityMatrix[3], ReactionBasis];
MatrixForm[ReactionToPhoton]

ReactionToPhoton . {(Subscript[P, t]), (Subscript[P, n]), (Subscript[P, ℓ])} // ColumnForm

Notice that if the acceptance is symmetric wrt the scattering plane, the \(TraditionalForm\`\(x\&^\)\) and \(TraditionalForm\`\(z\&^\)\) components are determined by orthogonal linear combinations of the helicity dependent \(TraditionalForm\`\(t\&^\)\) and \(TraditionalForm\`\(ℓ\&^\)\) components while the \(TraditionalForm\`\(y\&^\)\) component is determined by the helicity-independent \(TraditionalForm\`\(n\&^\)\) component of polarization.

Polarimeter basis

Derivation based upon vector cross product

In this section we derive an alternative {\(TraditionalForm\`\(a\&^\)\),\(TraditionalForm\`\(b\&^\)\),\(TraditionalForm\`\(c\&^\)\)} basis that avoids the inconvenient sign reversals exhibited by the reaction basis as \(TraditionalForm\`\(p\&^\)\) moves from one side of \(TraditionalForm\`\(q\&^\)\) to the other.  We call this the polarimeter basis because a nonmagnetic polarimeter with small acceptance would naturally be placed with its central \(TraditionalForm\`c\&^\) axis along the ejectile momentum and its sideways \(TraditionalForm\`a\&^\) axis parallel to the scattering plane, which is normally horizontal in the lab.  Furthermore, since we would not turn the polarimeter upside down, we would like to keep the vertical component of \(TraditionalForm\`\(b\&^\)\) positive.  It is simplect to construct the polarimeter basis using \(TraditionalForm\`\(c\&^\) = ℓ\&^\), \(TraditionalForm\`a\&^ ∝ y\&^×ℓ\&^\), and \(TraditionalForm\`b\&^ = c\&^×a\&^\).

\(c\&^ = ℓ\&^\)

\(a\&^ = NormalizedCrossProduct[{0, 1, 0}, ℓ\&^]\)

\(b\&^ = Cross[c\&^, a\&^] // Simplify\)

\(a\&^ . b\&^ == b\&^ . c\&^ == a\&^ . c\&^ == 0 // Simplify\)

In contrast with the reaction basis, the polarimeter basis has the desirable property that its vertical component is always positive and that \(TraditionalForm\`\(\(a . \)\&^\) \(x\&^\)\) does not reverse sign as \(TraditionalForm\`\(p\&^\)\) moves from one side of \(TraditionalForm\`\(q\&^\)\) to the other.

\(\(PolarimeterBasis = {a\&^, b\&^, c\&^};\)\)

PolarimeterBasis /. ϕ -> 0 // Simplify

PolarimeterBasis /. ϕ -> π // Simplify

Derivation using rotation matrix

It is also instructive to express the polarimeter basis in terms of Euler angles.  This basis can be obtained from the reaction basis using a final rotation about the \(TraditionalForm\`ℓ\&^\) axis through an angle ψ designed to eliminate \(TraditionalForm\`a\&^ . \(y\&^\)\).  Trial solutions are obtained by solving the following equation.

eq = 
      0 == Part[Transpose[euler[ϕ, θ, ψtemp]], 1, 
          2]

sol = Solve[eq, ψtemp]

To choose between these solutions we must impose a subsidiary condition.  Since we would not turn the polarimeter upside down, we would like to keep the vertical component of the second basis vector positive.

by[ψ_] := 
      Part[Transpose[euler[ϕ, θ, ψ]], 2, 2] // 
        Simplify

bytemp = by[ψtemp] /. sol

Table[
        Sign[bytemp] /. {θ -> (π/4)}, {ϕ, (π/4), 
          7  (π/4), (π/4)}] // MatrixForm

Table[
        Sign[bytemp] /. {θ -> ((3  π)/4)}, {ϕ, (π/4), 7  (π/4), (π/4)}] // MatrixForm

Unfortunately, it is not possible to obtain this behavior from a single solution; the form of these solutions also presents problems when PowerExpand is used to simplify subsequent results.  Recognizing that for most orientations either solution 3 or solution 4 yields the desired behavior, we attempt to find a simpler solution using PowerExpand

ψ3 = ψtemp /. 
          sol[[3]];
{Cos[ψ3], Sin[ψ3], Tan[ψ3]} // Simplify // 
      PowerExpand

ψ4 = ψtemp /. 
          sol[[4]];
{Cos[ψ4], Sin[ψ4], Tan[ψ4]} // Simplify // 
      PowerExpand

Actually, it is more efficient to identify {Cos[ψ], Sin[ψ]} with the projections of \(TraditionalForm\`\(a\&^\)\) upon \(TraditionalForm\`\(t\&^\)\) and \(TraditionalForm\`\(n\&^\)\), whereby

\({a\&^ . t\&^, a\&^ . n\&^} // Simplify\)

Thus, we demonstrate that the following representation does ensure a positive vertical component.

ψsol = 
        ArcTan[Cos[ϕ], -Cos[θ] Sin[ϕ]];

bytemp2 = by[ψsol];

Table[
        Sign[bytemp2] /. {θ -> (π/4)}, {ϕ, (π/4), 
          7  (π/4), (π/4)}] // MatrixForm

Table[
        Sign[bytemp2] /. {θ -> ((3  π)/4)}, {ϕ, (π/4), 7  (π/4), (π/4)}] // MatrixForm

Therefore, although it is difficult to obtain simple symbolic results, we have found a symbolic expression that appears to give the desired rotation for any choice of θ and ϕ.

Plot[
        Evaluate[
          Table[ψsol, {θ, 0, (π/2), (π/16)}]], {ϕ, 0, 
          2  π}];

Plot3D[ψsol, {θ, 0, π}, {ϕ, 0, 2  π}, 
        PlotPoints -> 25, 
        ViewPoint -> {-2.224,  -2.259,  1.184}];

We can transform from the reaction basis to the polarimeter basis by rotation about \(TraditionalForm\`ℓ\&^\) through angle ψ.

ReactionToPolarimeter = 
        TransformationMatrix[PolarimeterBasis, ReactionBasis];
MatrixForm[ReactionToPolarimeter]

Although I seem to have lost my earlier notes on this derivation, the following verifies that this result agrees with the polarimeter basis coded in epiprod.

Cos[ϕ]^2 + Cos[θ]^2 Sin[ϕ]^2 == 
        1 - Sin[θ]^2 Sin[ϕ]^2 // Simplify

Spectrometer basis

The spectrometer basis {\(TraditionalForm\`\(d\&^\), \(e\&^\), \(f\&^\)\)} is similar to the photon basis in that \(TraditionalForm\`\(e\&^\) = \(y\&^\)\) is vertical, but now we set \(TraditionalForm\`\(f\&^\)\) at some angle (Subscript[θ, s]) wrt to the nominal \(TraditionalForm\`\(q\&^\)\).

\(\({d\&^, e\&^, f\&^} = 
        Transpose[euler[0, θ\_s, 0]] // 
          Simplify;\)\)
\(SpectrometerBasis = {d\&^, e\&^, f\&^}\)

ReactionToSpectrometer = 
      TransformationMatrix[SpectrometerBasis, ReactionBasis]

ReactionToSpectrometer . {(Subscript[P, t]), (Subscript[P, n]), (Subscript[P, ℓ])} // 
      Simplify

SpectrometerToReaction = 
      TransformationMatrix[ReactionBasis, SpectrometerBasis]

SpectrometerToReaction . {(Subscript[P, d]), (Subscript[P, e]), (Subscript[P, f])} // Simplify